{
  description = "LESA OS";

  inputs = {
    # dafault unstable
    nixpkgs.url = "github:nixos/nixpkgs?ref=nixos-unstable";

    #latest stable
    nixpkgs-stable.url = "github:nixos/nixpkgs/nixos-25.05";

    zen-browser = {
      url = "github:0xc000022070/zen-browser-flake";
      inputs.nixpkgs.follows = "nixpkgs";
    };
  };

  outputs = {
    self,
    nixpkgs,
    nixpkgs-stable,
    zen-browser,
    ...
  } @ inputs: let
    system = "x86_64-linux";

    hosts = [
      {hostname = "ArcticFox";}
    ];

    makeSystem = {hostname}:
      nixpkgs.lib.nixosSystem {
        system = system;

        specialArgs = {
          inherit inputs hostname;
          pkgs-stable = import nixpkgs-stable {
            inherit system;
            config.allowUnfree = true;
          };
        };

        modules = [
          ./hosts/${hostname}/configuration.nix
        ];
      };
  in {
    nixosConfigurations =
      nixpkgs.lib.foldl' (
        configs: host:
          configs
          // {
            "${host.hostname}" = makeSystem {
              inherit (host) hostname;
            };
          }
      ) {}
      hosts;
  };
}